Afficheur de Netsplit spécial

[coders-irc_Bot]

;Cette ligne vous permet de modifier la couleur, le logo et la couleur des pseudos
alias -l kikunetlogo return $+($chr(91),$chr(31),$chr(3),07,NetSplit,$chr(3),$chr(31),$chr(93),$chr(3),14)
;Permets de choisir le symbole qui séparera les pseudos (utilisez //echo -ag $asc($$?) pour avoir le numéro du symbole. Exemple ici le symbole est "," donc son code est 44 donc vous devez mettre $chr(44) 44)
alias -l kikunetcharsep return $chr(44) 44
;permet de choisir le nombre de pseudo affiché sur une seule ligne avant de passer à la suivante
alias -l kikunetmaxnick return 20
alias -l safe return $!decode( $encode($1-, m) ,m)

on ^*:quit:{
  var %b $comchan($nick,0)
  while %b {
    if $0 == 2 && $count($1,.) > 0 && $count($2,.) > 0 {
      hadd -m $comchan($nick,%b) $nick $1-
      $+(.timerkikunet,$cid,$comchan($nick,%b)) -h 1 3000 kikunetlook $safe($comchan($nick,%b)) $(|) hfree $safe($comchan($nick,%b))
    }
    else {
      if ($nick == $me) echo -t $comchan($nick,%b) [Quit] Tu quittes ce serveur : $1-
      else echo -t $comchan($nick,%b) [Quit] $nick $gettok($fulladdress,2,33) $1- [ $+ $calc($nick($comchan($nick,%b),0) - 1) Users]
    }
    dec %b
  }
  if ($query($nick)) echo -t $query($nick) [Quit] $nick $address($nick,2) $1-
  haltdef
}
alias -l kikunetlook {
  var %i 1,%max $hget($1,0).item
  while %i <= %max {
    var %txt $+(%txt,$gettok($kikunetcharsep,1,32),$hget($1,%i).item)
    inc %i
    if $numtok(%txt,$gettok($kikunetcharsep,2,32)) >= $kikunetmaxnick || !$hget($1,%i).item { echo -t $1 %netcolor $sorttok($mid(%txt,2-),$gettok($kikunetcharsep,2,32)) $iif(%max == 1,$hget($1,%max).data) | unset %txt }
  }
  if ($hget($1) && %max > 1) echo -t $1 %netcolor %max $+(personne,$iif(%max > 1,s)) $+(perdue,$iif(%max > 1,s)) $hget($1,%max).data
}

Il a la particularité comme vous pouvez le voir dans les screenshots de rassembler les netsplits en quelques lignes.
Pourquoi utiliser ce code ? Cela vous évitera d'avoir des dizaines de lignes identiques en cas de netplits en ayant selon moi un rendu plus joli.
J'ai mis 3alias juste en dessous qui vous permettent de règler à votre convenance mon système.
Toutefois je n'ai pas permis la configuration des quits normaux vous allez devoir le faire vous même.
Ce que je veux dire par là c'est qu'au niveau des couleurs et de la présentation des quits normaux je n'ai rien fait à vous de mettre vos couleurs selon vos désires modifier l'affichage donc voilà.