chain

June 15, 2022

I have retested the downloads and it seems to be working, there have been people telling me there's issues.

So i have tested it and seems to work fine. Please let me know if there's anymore issues with the archive downloads

June 15, 2022

Here's a Zip file of some old IRC Scripts if your interested in keeping for your own archives.

I take no responsibility to any damage caused by any noobs running somethings that I might upload for the mIRC community as I did not make even a dent of what I will be sharing. Anything I know for sure is dangerous I will surely Mark it as Such and if I do Heed the Warning. Like GtBots. for instance those can be dangerous toys if not used properly. This is for your own warning. coders-Resources is not responsible when or how you use these scripts.

1325329690_mIRCScripts.zip

June 12, 2022

we've been on for years & we have moved up with a few more chatter's coming but nothing like other server's.

Mind you it would be nice to see it grow. Would have to discuss it with my partner Eyecu he dose all the updates and server stuff!

June 11, 2022

Today I went to go see an old italian scripting site and seen that it hasn't been used in quite some time and has been let go. and all of the downloads shut down. Same has happen with Hawkee spammers left and right and no one controlling the forums.

This is why I've been collecting all the snippets and codes from various script sites to keep all the codes in archives for reference and just to save them. My good friend err0r from Tg007 has done that also. it's a shame to see scripting websites closing and not as popular as they use to be, it saddens me that people that have spend all that time coding will be lost and forgotten.

Hawkee - A Writing Platform for Web Developers

https://calabria-irc.forumfree.it/

very popular scripting sites in the day!!

Report · June 11, 2022

Last night I had fun chatting with a huge group on gotalk.to with some Rizon IRC users

Was a blast talking about how script's and websites and coding. I'm pretty much on a lot of server's and i even have a server, and hearing that chat isn't truly dead made me realize it's truly not you just have to find the right rooms on the right server.

Geekshed is quite active and also Rizon I believe all servers have some chat but just locating them is what you need to do. I find scripting rooms less active as they mainly chat on script forum then in there room, but there still there watching in case you need a help in coding. I've made quite a lot of new friends on each server and have caught up with a few from hawkee well know scripter's. And there still active and continue to be active just that they work and some have families so time is less. But isn't that with everyone now. So I believe chat hasn't died its just the time schedule that effects user's now. but go on weekends and wow chat has risen :04a97f13:

June 11, 2022

THERE are not many sites that keep abreast of IRC. Many wrongly assume that it barely exists anymore, but it has been around for a very long time. As netsplit.de puts it: “Internet Relay Chat (short: IRC) [...] a chat protocol that was developed in 1988 and that’s internationally used for text based communication over the Internet.”

Here’s a list of currently-known networks “in alphabetical order” (Techrights has only just been added, but like many other networks it was “unseen” for a long time).

Based on these known networks alone, the number of users peaks at around third of a million:

“The largest of them that take part in our comparison of IRC networks are contained in the top 100 list,” the page says, “but there are also some IRC networks that are big and run out of competition.”

June 9, 2022

;---------<  Robo-X - Topic Command:  >-----------
on 1:text:@topic *:#robots: {
  if ( $nick isop $chan || $nick ishop $chan ) {
    set %topic $2-
    topic $chan Topic: 4 %topic / 7 %status / 3 %static-a / 9 %static-b
  }
}
on 1:text:@status *:#robots: {
  if ( $nick isop $chan || $nick ishop $chan ) {
    set %status $2-
    topic $chan Topic: 4 %topic / 7 %status / 3 %static-a / 9 %static-b
  }
}

on 1:text:@static-a *:#robots: {
  if ( $nick isop $chan || $nick ishop $chan ) {
    set %static-a $2-
    topic $chan Topic: 4 %topic / 7 %status / 3 %static-a / 9 %static-b
  }
}

on 1:text:@static-b *:#robots: {
  if ( $nick isop $chan || $nick ishop $chan ) {
    set %static-b $2-
    topic $chan Topic: 4 %topic / 7 %status / 3 %static-a / 9 %static-b
  }
}

June 9, 2022

alias sil {
  if ($me isop $chan) || ($me ishop $chan) {
    if (!$1) || (!$2) { echo -at * Error: Incorrect syntax used, /sil <nick> <timer in minutes> }
    elseif ($1) || ($2) {
      mode $chan +bb ~q: $+ $address($1,2) ~n: $+ $address($1,2)
      writeini Silence.ini $$1 chan $active
      if ($$1 ishop $active) { writeini Silence.ini $1 status HOP | mode $active -h $1 }
      if ($$1 isvoice $active) { writeini Silence.ini $1 status VOP | mode $active -v $1 }
      $iif($$1 isreg $active,writeini Silence.ini $1 status REG)
      .timer 1 $calc($2 * 60) desil $1 $address($1,2) $chan
    }
  }
}

on *:JOIN:#: {
  if ($ini(Silence.ini,$nick,chan)) {
    if ($readini(Silence.ini,$nick,status) == HOP) {
      mode $chan -h $nick
    }
    elseif ($readini(Silence.ini,$nick,status) == VOP) {
      mode $chan -v $nick
    }
  }
}

alias -l desil {
  if ($1 ison $3) {
    if ($readini(Silence.ini,$1,status) == HOP) { mode $$3 +h $1 | remini Silence.ini $1 }
    if ($readini(Silence.ini,$1,status) == VOP) { mode $$3 +v $1 | remini Silence.ini $1 }
    mode $3 -bb ~q: $+ $2 ~n: $+ $2
  }
  elseif ($1 !ison $3) { mode $3 -bb ~q: $+ $2 ~n: $+ $2 | remini Silence.ini $1 }
}

June 9, 2022

MuteBanEnforce by Ford_Lawnmower irc.GeekShed.net #Script-Help
menu nicklist {
  .$iif(!$hget(MuteEnforce,$+($network,$chan,$address($$1,2))),$style(2)) RemoveMute $$1: {
    var %mask $+($network,$chan,$address($$1,2))
    hdel MuteEnforce %mask
    if ($timer(%mask).com) {
      $v1
      .notice $$1 Your ban has been lifted early! You may now speak in $+($chan,.) Please try not to repeat the same activity that caused you to be muted.
      $+(.timer,%mask) off
    }
    else mode $chan -b $+(~q:,$address($$1,2))
  }
  .Mute $$1
  ..3 Minutes:mute $$1 180 $$?="Reason for Muting $$1"
  ..5 Minutes:mute $$1 300 $$?="Reason for Muting $$1"
  ..10 Minutes:mute $$1 600 $$?="Reason for Muting $$1"
  ..30 Minutes:mute $$1 1800 $$?="Reason for Muting $$1"
  ..60 Minutes:mute $$1 3600 $$?="Reason for Muting $$1"
  ..Forever:mute $$1 $$?="Reason for Muting $$1"
}
alias mute {
  clipboard $$1
  var %nick $cb(1)
  if (%nick ison $chan) {
    ialcheck %nick
    var %usermodes $replace($remove($nick(#,%nick).pnick,%nick),~,q,&,a,!,a,@,o,%,h,+,v), %addy $iif($address(%nick,2),$v1,%nick)
    mode $chan $+(+b-,%usermodes) $+(~q:,%addy) $str($+(%nick,$chr(32)),$len(%usermodes))
    hadd -m MuteEnforce $+($network,$chan,%addy) mute
    if ($$2 isnum) {
      $+(.timer,$network,$chan,%addy) 1 $$2 removeMute $+($network,$chan,%addy) $chan $+(-b+,%usermodes) $+(~q:,%addy) $str($+(%nick,$chr(32)),$len(%usermodes))
      msg $chan $+(,%nick,) You have been Muted! Duration: $duration($2) Reason: $3-
    }
    else msg $chan %nick You have been Muted! $+(Reason:,$2-)
  }
  else echo -a %nick is not on $chan
}
alias -l ialcheck {
  if (!$ial($1)) .who $1
}
alias -l removeMute {
  if ($($+($,$0),2) !ison $2) mode $2 -b $4
  else mode $2-
  hdel MuteEnforce $1
}
alias -l parseMode {
  tokenize 32 $1
  var %start 1, %finish $len($1), %+-, %modes -1, %location $+(parseMode,$chr(3),$network,$chr(3),$chan)
  while (%start <= %finish) {
    if ($mid($1,%start,1) isin +-) { %+- = $replace($v1,+,1,-,-1) | inc %modes }
    elseif ($mid($1,%start,1) isin qaohvb) {
      var %mode $+($v1,$($+($,$calc(%start - %modes)),2))
      hadd -m %location %mode $calc($hget(%location,%mode) + %+-)
    }
    inc %start
  }
  var %hash $regsubex($regsubex($str(.,$hget(%location,0).item),/(.)/g,$+($hget(%location,\n).data,$hget(%location,\n).item,$chr(32))),/(\b0[^\s]*)/g,)
  if ($hget(%location)) hfree $v1
  var %count 1, %max $numtok(%hash,32), %return, %temp
  while (%count <= %max) {
    %temp = $gettok(%hash,%count,32)
    %return = $+(%return,$chr(32),$iif($left(%temp,1) == -,$+(-,$mid(%temp,3)),$+(+,$mid(%temp,2))))
    inc %count
  }
  return %return
}
On !*:rawmode:#: {
  checkMutes $network $chan $parsemode($1-)
}
alias -l checkMutes {
  var %network $1, %chan $2, %modes $3-
  tokenize 32 %modes
  checkMute %network %chan $*
}
alias -l checkMute {
  var %mode $left($3,2), %target $mid($3,3)
  if ((%mode isincs +v+h+o+a+q) && ($hget(MuteEnforce,$+($1,$2,$address(%target,2))))) mode $2 $replace(%mode,+,-) %target
  elseif ((%mode == -b) && ($hget(MuteEnforce,$+($1,$2,$gettok(%target,-1,58))))) mode $chan +b %target
}

June 9, 2022

menu channel {
  Peak Script v1.1:peakdia
}

alias -l peakdia {
  $iif($dialog(multi_peak),dialog -v,dialog -m multi_peak) multi_peak
}

dialog multi_peak {
  title "Peak Dialog by Danneh"
  size -1 -1 144 122
  option dbu
  box "Peak Setup", 4, 2 20 140 100
  combo 5, 5 38 60 50, sort size
  text "Networks:", 6, 5 28 25 8
  button "Add", 7, 5 90 30 12
  button "Del", 8, 36 90 30 12
  combo 9, 78 38 60 50, size
  text "Channels:", 10, 78 28 24 8
  button "Add", 11, 78 90 30 12
  button "Del", 12, 109 90 30 12
  button "Ok", 13, 29 104 37 12, ok
  button "Cancel", 14, 78 104 37 12
  box "Master Switch:", 15, 2 2 63 17
  check "On/Off", 16, 16 8 36 10
  box "Setting:", 17, 79 2 63 17
  check "Op's Only Switch", 18, 82 8 59 10
  menu "File", 1
  item "Unset All", 2, 1
  item "Exit", 3, 1
}

on *:DIALOG:multi_peak:init:*: {
  var %a = $numtok(%peak.networks,44)
  while (%a) {
    did -a $dname 5 $gettok(%peak.networks,%a,44)
    dec %a
  }
  if (%peakmaster == on) {
    did -c $dname 16
  }
  if (%peakmaster == $null) {
    did -b $dname 5,7-9,11,12,18
  }
  if (%peakops == on) {
    did -c $dname 18
  }
}

on *:DIALOG:multi_peak:menu:2,3: {
  if ($did == 2) {
    unset %peak.*
    did -r $dname 5,9
  }
  if ($did == 3) {
    dialog -x multi_peak multi_peak
  }
}

on *:DIALOG:multi_peak:sclick:5,7,8,11,12,16,18: {
  if ($did == 5) {
    did -r $dname 9
    var %a = $numtok(%peak. [ $+ [ $did($dname,5).text ] ],44)
    while (%a) {
      did -a $dname 9 $gettok(%peak. [ $+ [ $did($dname,5).text ] ],%a,44)
      dec %a
    }
  }
  if ($did == 7) {
    if (!$did($dname,5).text) { noop $input(Please enter a Network to add for Peaks.,o) }
    elseif ($istok(%peak.networks,$did($dname,5).text,44)) { noop $input(The Network you entered is already setup for Peaks.,o) }
    else {
      set %peak.networks $addtok(%peak.networks,$did($dname,5).text,44)
      did -a $dname 5 $did($dname,5).text
    }
  }
  if ($did == 8) {
    if (!$did($dname,5).text) { noop $input(Please enter a Network to remove from Peaks.,o) }
    elseif (!$istok(%peak.networks,$did($dname,5).text,44)) { noop $input(The Network you wish to remove is not in the Peak setup.,o) }
    else {
      set %peak.networks $remtok(%peak.networks,$did($dname,5).text,44)
      did -r $dname 5
      var %a = $numtok(%peak.networks,44)
      while (%a) {
        did -a $dname 5 $gettok(%peak.networks,%a,44)
        dec %a
      }
      $iif(%peak.networks == $null,unset %peak.networks)
    }
  }
  if ($did == 11) {
    if (!$did($dname,5).text) { noop $input(Please select a Network to add channels to.,o) }
    elseif (!$did($dname,9).text) { noop $input(Please enter a channel to add to the Peak Setup.,o) }
    elseif ($istok(%peak. [ $+ [ $did($dname,5).text ] ],$did($dname,9).text,44)) { noop $input(The Selected channel name is already setup for Peaks.o) }
    else {
      set %peak. [ $+ [ $did($dname,5).text ] ] $addtok(%peak. [ $+ [ $did($dname,5).text ] ],$did($dname,9).text,44)
      did -a $dname 9 $did($dname,9).text
    }
  }
  if ($did == 12) {
    if (!$did($dname,5).text) { noop $input(Please select a Network to remove channels from.,o) }
    elseif (!$did($dname,9).text) { noop $input(Please enter a channel to remove from the Peak Setup.,o) }
    elseif (!$istok(%peak. [ $+ [ $did($dname,5).text ] ],$did($dname,9).text,44)) { noop $input(The Selected channel name is not in the setup for Peaks.o) }
    else {
      set %peak. [ $+ [ $did($dname,5).text ] ] $remtok(%peak. [ $+ [ $did($dname,5).text ] ],$did($dname,9).text,44)
      unset %peak. [ $+ [ $did($dname,5).text ] $+ ] . [ $+ [ $did($dname,9).text ] $+ ] .*
      did -r $dname 9
      var %a = $numtok(%peak. [ $+ [ $did($dname,5).text,44)
      while (%a) {
        did -a $dname 9 $gettok(%peak. [ $+ [ $did($dname,5).text ] ],%a,44)
        dec %a
      }
      $iif(%peak. [ $+ [ $did($dname,5).text ] ] == $null,unset %peak. [ $+ [ $did($dname,5).text ] ])
    }     
  }
  if ($did == 16) {
    if ($did(16).state == 0) {
      unset %peakmaster
      noop $input(Peak script has been disabled.,o,Success!)
      did -b $dname 5,7-9,11,12,18
    }
    if ($did(16).state == 1) {
      set %peakmaster on
      noop $input(Peak script has been enabled.,o,Success!)
      did -e $dname 5,7-9,11,12,18
    }
  }
  if ($did == 18) {
    if ($did(18).state == 0) {
      unset %peakops
      noop $input(Peak trigger now works for everyone.,o,Success!)
    }
    if ($did(18).state == 1) {
      set %peakops on
      noop $input(Peak trigger now works for Ops only.,o,Success!)
    }
  }
}

on *:JOIN:#: {
  if ($istok(%peak. [ $+ [ $network ] ],$chan,44)) {
    if (!%peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak) {
      set %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak $nick($chan,0)
      set %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .ctime $ctime
    }
    else {
      if ($nick($chan,0) <= %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak) { HALT }
      else {
        set %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak $nick($chan,0)
        msg $chan New Peak: %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak Last Peak: $duration($calc($ctime - %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .ctime)) ago.
        .timer 1 3 set %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .ctime $ctime
      }
    }
  }
}

on *:TEXT:!Peak:#: {
  if ($istok(%peak. [ $+ [ $network ] ],$chan,44)) {
    if (%peakops == on) {
      if ($nick isop $chan) {
        msg $chan Current Peak: %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak Peak Set: $duration($calc($ctime - %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .ctime)) ago.
      }
    }
    if (%peakops == $null) {
      msg $chan Current Peak: %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .peak Peak Set: $duration($calc($ctime - %peak. [ $+ [ $network ] $+ ] . [ $+ [ $chan ] $+ ] .ctime)) ago.
    }
  }
}

June 9, 2022

menu * {
  Away Dialog:awaydia
}

dialog awaydia {
  title "Away Dialog"
  size -1 -1 200 180
  option pixels
  tab "Set Away", 1, 0 0 199 150
  tab "Set Back", 12
  button "Ok", 4, 31 151 65 25, ok flat
  button "Cancel", 5, 103 151 65 25, cancel flat
  box "Away", 6, 6 27 184 110, tab 1
  edit "", 7, 72 41 110 20, tab 1
  text "Away Nick:", 8, 12 42 55 17, tab 1
  text "Away Msg:", 9, 11 65 55 17, tab 1
  edit "", 10, 72 64 108 20, tab 1
  button "Set Away", 11, 65 99 65 25, tab 1
  box "Back", 13, 6 27 184 110, tab 12
  text "Back Nick:", 14, 12 42 55 17, tab 12
  edit "", 15, 72 41 110 20, tab 12
  button "Set Back", 16, 65 82 65 25, tab 12
  menu "File", 2
  item "Exit", 3, 2
}

on *:DIALOG:awaydia:init:*: {
  if (!%away.nick) && (!%back.nick) {
    set %away.nick $$?="Please enter your away nick:"
    set %back.nick $$?="Please enter your normal nick:"
    did -a $dname 7 %away.nick
    did -a $dname 15 %back.nick
  }
  else {
    did -ra $dname 15 %back.nick
    did -ra $dname 7 %away.nick
  }
}

on *:DIALOG:awaydia:sclick:11,16: {
  if ($did == 11) {
    if (!$did($dname,10).text) {
      scon -a nick $did($dname,7).text
    }
    else {
      scon -a away $did($dname,10).text
      scon -a nick $did($dname,7).text
    }
  }
  if ($did == 16) {
    if ($away == $true) {
      scon -a away
      scon -a nick $did($dname,15).text
    }
    else {
      scon -a nick $did($dname,15).text
    }
  }
}

on *:DIALOG:awaydia:menu:3: {
  dialog -x awaydia awaydia
}

alias -l awaydia {
  $iif($dialog(awaydialog),dialog -v,dialog -m awaydia) awaydia
}

June 9, 2022

;theSLAP 2.0
on *:join:#:{
  if ($nick != $me) {
    var %u users_ $+ $nick
    if (!$readini(slapthegame.ini,%u,hp)) {
      writeini slapthegame.ini %u hp 100
      writeini slapthegame.ini %u money 15
    }
  }
  ;notice $nick Wellcome. This Channel has SLAPtheGame installed. go on and !slap :)
}
on *:text:!thegame:#:{
  notice $chan Noob in town :) !slap $nick everyone :D
  msg $chan !slap, !heal, !money, !gamble, !stats, !ladder, !alive, !beer, !punch (2.0)
}
on *:text:!money:#:{
  var %u users_ $+ $nick
  if ($readini(slapthegame.ini,%u,money) < 15) {
    writeini slapthegame.ini %u money 15
    notice $nick Your wallet has been refiled with 15coins
  }
  else {
    notice $nick Oi! this isn't a bank, Sir.
  }
}

on *:text:!slap*:#:{
  if (!$2) {
    notice $nick usage: !slap NICK
    notice $nick !slap command will trigger the end of the world. Go on, !slap someone :)
    halt
  }
  var %s1H $readini(slapthegame.ini,$+(users,_,$nick),hp)
  var %s2H $readini(slapthegame.ini,$+(users,_,$2),hp)
  if (%s2H < 1) && ($2 != me) {
    msg $chan player $2 is dead. You can !heal $2 for the price of 15coins and slap him to death again :)
    halt
  }
  if (%s1H > 0) {
    var %slapper $nick
    var %slapped $2

    if (%slapped !ison $chan) && (%slapped != me) {
      msg $chan That payer isn't online, not fair.
      halt
    }
    if (%slapped == me) { msg $chan Ye, I'm gona slap you real nice :D whatta tool! :) | var %slapper $me | var %slapped $nick }
    ;if (%slapped == $me) && ($nick != MoshMage) { msg $chan You wish? | halt }

    var %slap $rand(0,100)
    ;msg $chan Slap power %slap
    if (%slap >= 70) {
      var %slap_sneak 1
      slap2 $chan %slapper %slapped %slap %slap_sneak
    }
    if (%slap > 50) && (%slap <= 69) {
      ;notice %slapped OI! !dodge NOW or you'll be slapped!! $chan
      inc %slaps
      ;.$+(timer,Slap,%slaps) 1 5 slap2 $chan %slapper %slapped %slap %slap_sneak
      slap2 $chan %slapper %slapped %slap %slap_sneak
    }
    if (%slap == 50) {
      slap2 $chan %slapper %slapped %slap
      msg $chan %slapped was watching sharply and grabbed %slapper $+ 's hand, no harm done.
    }
    if (%slap < 50) {
      slap2 $chan %slapper %slapped %slap
    }
  }
  else {
    msg $chan Look! A ghost trying to Slap. How funny :)
    notice $nick you are DEAD. !heal to buy 100hp.
  }
}
alias slap2 {
  var %dmg $4
  var %slapped $+(users,_,$3)
  var %slapper $+(users,_,$2)
  var %s1H $readini(slapthegame.ini,%slapper,hp)
  var %s2H $readini(slapthegame.ini,%slapped,hp)
  if (%dmg < 50) {
    var %life $calc(%s1H - %dmg)
    if (%life < 0) { var %life 0 }
    writeini slapthegame.ini %slapper hp %life
    msg $1 $3 saw right trhough $2 $+ 's movement and counterslaps. $iif(%life < 1,AAAnd $2 is knockedout!! Cheers $+ $chr(44) $3 $+ !)
    notice $2 $3 counterslaped you, $iif(%life > 0, you have %life $+ hp,you're dead. !heal)
    if (%life < 0) {
      var %deaths $readini(slapthegame.ini,%slapper,deaths)
      var %deaths $calc(%deaths +1)
      var %kills $readini(slapthegame.ini,%slapped,kills)
      var %kills $calc(%kills +1)
      writeini slapthegame.ini %slapped kills %kills
      writeini slapthegame.ini %slapper deaths %deaths
    }
  }
  if (%dmg == 50) {
    msg $1 $3 was watching sharply and grabbed $2 $+ 's hand, no harm done. Also.. fucking amazing.
  }
  if (%dmg > 50) {
    var %life $calc(%s2H - %dmg)
    echo -a %life - %dmg - %s2H
    if (%life < 1) {
      var %deaths $readini(slapthegame.ini,%slapped,deaths)
      var %kills $readini(slapthegame.ini,%slapper,kills)
      var %deaths $calc(%deaths +1)
      var %kills $calc(%kills +1)
      writeini slapthegame.ini %slapper kills %kills
      writeini slapthegame.ini %slapped deaths %deaths
    }
    if (%life < 0) { var %life 0 }
    writeini slapthegame.ini %slapped hp %life
    if ($5 > 0) {
      var %money $rand(1,50)
      var %s1M $readini(slapthegame.ini,%slapper,money)
      var %s2M $readini(slapthegame.ini,%slapped,money)

      var %coins $calc(%money + %s1M)
      var %slapmsg $2 sneaks in on $3 and smacks his[er] face upright.
      notice $2 Whoa! whattasmack! You popped %money $+ coins from $3 $+ 's pocket :) (Wallet: %coins $+ )
      writeini slapthegame.ini %slapper money %coins
      ;steal ability?
      ;notice %slapped That Sir, was a Gloved Slap in teh Face. Also, you lost some coins.
      ;writeini slapthegame.ini %slapper money $calc(%s2M - %money)
    }
    if (!%slapmsg) { var %slapmsg $2 boldly slaps $3 $+ . }
    msg $1 %slapmsg
    notice $3 $2 slaped you, $iif(%life > 0, you have %life $+ hp,you're dead. !heal)
  }
  dec %slaps
  ;echo -a SLAPED $3 - $2 : %dmg
}
on *:text:!heal*:#:{
  var %u users_ $+ $iif($2,$2,$nick)
  if ($readini(slapthegame.ini,%u,money)) {
    var %slapper users_ $+ $nick
    var %s1M $readini(slapthegame.ini,%slapper,money)
    if (%s1M >= 15) {
      var %money $calc(%s1M - 15)
      writeini slapthegame.ini %slapper money %money
      writeini slapthegame.ini %u hp 100
      notice $remove(%slapper,users_) Medic Kit used :) Wallet: %money
      if (%u != $remove(%slapper,users_)) { msg $chan $nick healed $2 }
    }
    else {
      msg $chan Not enough cash! (15coins. You have %s1M $+ )
    }
  }
  else {
    msg $chan Not enough cash! (15coins. You have %s1M $+ )
  }
}

on *:text:!gamble*:#:{
  if ($2 == tehBunny) {
    var %s2M $readini(slapthegame.ini,gamble,money)
    msg $chan tehBuny holds %s2M coins for the lucky winner :)
    halt
  }
  if (!$3) || ($2 !isnum) || ($3 !isnum) { describe $chan Gamble How to: !gamble <cash> <1, 2 or 3> }
  else {
    var %bet $2
    var %bet_nick users_ $+ $nick
    var %s1M $readini(slapthegame.ini,%bet_nick,money)
    if (%bet > %s1M) {
      msg $chan Mate, you're short on Cash.
      halt
    }
    var %s2M $readini(slapthegame.ini,gamble,money)

    ;var %lie $rand(0,1)
    var %box $rand(1,102)
    if (%box < 95) { var %bunny 0 }
    if (%box >= 95) { var %bunny 1 }

    if (%box <= 34) { var %box 1 }
    if (%box > 34) && (%box <= 68) { var %box 2 }
    if (%box > 68) { var %box 3 }
    var %prize $rand(1,500)
    if (%prize > 350) { var %prize item }
    else { var %prize $calc(%bet * 2) }
    var %prize $calc(%bet * 2)
    ;echo %box
    if ($3 == %box) {
      msg $chan $iif(!%bunny,Well done. Won %prize,WOW!WOW!WOW! $nick won 3te5hB6u7n11n15y!! Grand Prize is $calc(%s2M + %prize))
      if (%bunny < 1) { var %money $calc(%s1M + %prize) }
      if (%bunny == 1) { var %money $calc(%s1M + %prize + %s2M) }
      if (%prize) && ($nick !isin %beer) {
        msg $chan WOW! You have access to BOOZE! and !beer has its downs and lows but you can always get drunk on it :) (one hour 'till the bar closes)
        set %beer $addtok(%beer,$nick,32)
        .timerbeer_ $+ $nick 1 3600 set %beer $remtok(%beer,$nick,1,32)
      }
      writeini slapthegame.ini %bet_nick money %money
      notice $nick Your wallet has %money $+ . You won $iif(!%bunny,%prize,$calc(%s2M + %prize))
    }
    else {
      var %lost $calc(%s1M - %bet)
      msg $chan Better luck next time.. tehBunny $calc(%s2M + %prize)
      writeini slapthegame.ini gamble money $calc(%s2M + %prize)
      writeini slapthegame.ini %bet_nick money %lost
    }
  }
}
on *:text:!stats*:#:{
  var %u users_ $+ $iif($2,$2,$nick)
  if ($ini(slapthegame.ini,%u,0)) {
    unset %stats
    var %inis $ini(slapthegame.ini,%u,0)
    var %x 1
    ;echo %inis $ini(slapthegame.ini,%u,0)
    while (%x <= %inis) {
      set %stats %stats $+(,$ini(slapthegame.ini,%u,%x),:,$readini(slapthegame.ini,%u,$ini(slapthegame.ini,%u,%x)))
      ;echo  $ini(slapthegame.ini,%u,%x) $readini(slapthegame.ini,%u,$ini(slapthegame.ini,%u,%x))
      inc %x
    }
    if (%stats) {
      var %k $readini(slapthegame.ini,%u,kills)
      var %d $readini(slapthegame.ini,%u,deaths)
      var %m $readini(slapthegame.ini,%u,money)
      if (%k < %d) {
        var %score $calc( ( %k - ( 0.5 * %d ) ) * %m / 100)   
      }
      else {
        var %score $calc( ( %k - %d ) * %m / 100)
      }
      msg $chan $remove(%u,users_) stats are %stats score %score
    }
  }
}
on *:text:!ladder:#:{
  unset %nicks
  unset %l*
  var %x 0
  while (%x <= $ini(slapthegame.ini,0)) {
    var %u $ini(slapthegame.ini,%x)
    if ($me !isin %u) {
      var %k $readini(slapthegame.ini,%u,kills)
      var %d $readini(slapthegame.ini,%u,deaths)
      var %m $readini(slapthegame.ini,%u,money)
      if (%m <= 0) { var %m 1 }
      if (%k < %d) {
        var %score $calc( ( %k - ( 0.5 * %d ) ) * %m / 100)   
      }
      else {
        var %score $calc( ( %k - %d ) * %m / 100)
      }
      if (%score > 0) {
        set %lscore $addtok(%lscore,%score,32)
        var %f $remove(%u,users_)
        set %lnscore $addtok(%lnscore,$+(%f,$chr(40),%score,$chr(41)),32)
      }
    }
    inc %x
  }
  if (%lscore) {
    var %sscore $sorttok(%lscore,32,nr)
    var %w $numtok(%lscore,32)
    var %l 0
    while (%l <= %w) {
      var %snick $gettok(%sscore,%l,32)
      var %n $matchtok(%lnscore,%snick,1,32)
      set %nicks $addtok(%nicks,%n,32)
      inc %l
    }
  }
  msg $chan slapLadder %nicks
}
on *:text:!alive*:#:{
  var %u users_ $+ $iif($2,$2,0)
  if (%u == users_0) {
    var %x 1
    var %z 0
    while (%x <= $nick($chan,0)) {
      if ($nick($chan,%x) != $me) {
        var %n $+(users_,$nick($chan,%x))
        var %hp $readini(slapthegame.ini,%n,hp)
        if (%hp > 0) {
          var %n $remove(%n,users_)
          var %s $+(,%n,,$chr(40),%hp,$chr(41),hp)
          var %alives $addtok(%alives,%s,32)
          inc %z
        }
      }
      inc %x
    }
    if (%z) {
      msg $chan Found $numtok(%alives,32) White-Gloved Gent. %alives
    }
    if (!%z) {
      msg $chan OMG! OMG! EVERYONE IS DEAAAATH! This, sir, is a Ghost Town. !heal someone.
    }
  }
  else {
    var %life $readini(slapthegame.ini,%u,hp)
    var %c users_ $+ $nick
    var %c $readini(slapthegame.ini,%c,money)
    msg $chan Player $remove(%u,users_) is $iif(%life > 0,Alive : $+ $chr(41),Death and you have $+(%c,coins))
  }
}
on *:text:!punch*:#:{
  ;ONLY DRUNK MAN AND SMALL MINDED PEOPLE PUNCH!
  if (!$2) { msg $chan look at the drunktard, doesn't even know who to punch. }
  else {
    var %puncher users_ $+ $nick
    var %punched users_ $+ $2
    var %hp $readini(slapthegame.ini,%puncher,hp)
    var %hp2 $readini(slapthegame.ini,%punched,hp)
    if (%hp > 0) {
      var %w $+(*,$2,*)
      if (%hp2 <= 0) {
        msg $chan $nick stumbles his feet on $2 $+ 's grave. Only drunk man punch.
        var %lost $rand(1,20)
        var %hp $calc(%hp - %lost)
        writeini slapthegame.ini %puncher hp %hp
        notice $nick You lost %lost $+ hp, you have %hp health points.
        unset %hp2
      }
      elseif (!$read(slapthegame.ini,w,%w)) || ($nick !isin %beer) {
        msg $chan $nick Punches the air and stumbles on his feet. Only drunk man punch.
        var %lost $rand(1,20)
        var %hp $calc(%hp - %lost)
        writeini slapthegame.ini %puncher hp %hp
        notice $nick You lost %lost $+ hp, you have %hp health points.
        ;halt
      }
      else {
        var %p $rand(1,25)
        if ($nick isin %beer) {
          var %beers $readini(slapthegame.ini,%puncher,beers)
          var %tb $calc(%beers *0.5)
          var %p $calc(%p * %tb)
        }
        if (%p >= 25) {
          var %hp $readini(slapthegame.ini,%punched,hp)
          var %f $calc(%hp - 50)
          if (%f > 0) {
            msg $chan It's amazing HOW $nick landed that punch. $remove(%punched,users_) $+ 's face will swell. %beers beer mugs were consumed for our amuse :)
            notice $remove(%punched,users_) You suffered a punch to teh face. $nick $+ 's little punk. you have %f $+ hp.
          }
          else {
            msg $chan the Drunktard punch: It can, and did, Kill. $remove(%punched,users_) Died. (note that, to land this punch $nick drunk %beers beer mugs)
            notice $remove(%punched,users_) That flippin honourless drunkar, $nick $+ , punched you. You were knocked out, !heal
          }
          notice $nick After such an amazing performance, the effect of the booze went away. such a shame.
          writeini slapthegame.ini %punched hp %f
          writeini slapthegame.ini %puncher beers 0
          set %beer $remtok(%beer,$nick,1,32)
        }
        else {
          msg $chan $nick Stumbles down for our amuse. Good one, Jester! :)
          var %hp $readini(slapthegame.ini,%puncher,hp)
          var %f $calc(%hp - 50)
          if (%f > 0) {
            notice $nick You bashed your head while on that poor performance. %f $+ hp.
          }
          else {
            notice $nick That blow to the head was really something. You knocked yourself out. !heal
          }
          writeini slapthegame.ini %puncher hp %f
        }
      }
    }
    else {
      msg $chan You are death, nick. !heal before punching. (Only drunk man punch.)
    }
  }
}

;items.name_price[-quantity]
;
;beer.30-1

on *:text:!beer*:#:{
  if ($nick !isin %beer) {
    msg $chan Bar's VIP only. earn vip status by !gambleing your money away :)
  }
  else {
    if ($2) {
      msg $chan Oh yeah, i know you wantz teh $iif($2 isnum,$2 beer mugs,beer mug) fast.
    }
    var %u users_ $+ $nick
    var %m $readini(slapthegame.ini,%u,money)
    var %b $readini(slapthegame.ini,%u,beers)
    if ($2 isnum) { var %hm $2 }
    if (%hm > 1) {
      var %m $calc(%m - (%hm * 30))
      var %b $calc(%b + %hm)
    }
    elseif (!%hm) || (%hm == 1) {
      var %m $calc(%m -30)
      var %b $calc(%b +1)   
    }
    if (%m > 0) {
      msg $chan $nick BOUGHT A BEER MUG! KEEP BEING AWESOME!
      writeini slapthegame.ini %u beers %b
      writeini slapthegame.ini %u money %m
    }
    if (%m < 0) {
      msg $chan $nick You poor twat. You already spent your money?! $duration($timer(beer_ $+ $nick).secs,2) till you loose Bar access
    }
  }
}

June 9, 2022

on *:TEXT:*:# {
  set %last.speaker $nick
}

alias hug {
  if ( $1- == $null ) {
    describe # hugs 12 $chan
  }
  elseif ( $1- = last ) {
    describe # huggles7 %last.speaker $+ !
  }
  else {
    describe # hugs3 $1.
  }
}

May 21, 2022

The latest beta is v7.68.1159 and can be downloaded here. It includes the following changes

How to install:

Let's assume your mIRC is installed in D:\mIRC\

Copy and save the script code in a file. For example: youtube_title.mrc
Put the saved file in your scripts folder (example: D:\mIRC\scripts)
Open mIRC and do: //load -rs scripts/youtube_title.mrc

How to Uninstall:

Open mIRC and do: //unload -rs scripts/youtube_title.mrc
That's it. No garbage or variables left behind.

The script can easily break if YouTube make changes to their website.
If it is broken or you find a bug or you have a suggestion - leave a comment below.
I will try to keep the script in working condition and fix bugs as soon as possible.

; Simple YouTube Title Announcer v0.1 - MMX 2022
; Requires mIRC v7.56+ (because of $urlget)

ON $*:TEXT:/(https\x3a\/\/|www\.)([\S]*youtube\.com[\S]+v\=|youtu\.be\/)([\S]{11})/Si:#:{
  if ($regml(3)) {
    var %url $+(https://m.youtube.com/watch?persist_app=1&app=m&v=,$regml(3))
    var %id $urlget(%url,gbi,&ytdata,yt_get_title $chan)
  }
}
alias -l yt_get_title {
  var %chan $1, %id $2
  if ($bfind($urlget(%id).target,1,/title":\{"runs":\[\{"text":"(.*?)"\}/Sig).regex) {
    msg %chan 01You00,04Tube: $yt_dehex($regml(1))
  }
}
alias -l yt_dehex {
  var %title $regsubex($1-,/\\u(.{4})/ig,$chr($base(\1,16,10)))
  return $replace(%title,\",",\\,\,\\\\,\\)
}

May 6, 2022

So people have been asking for the website of the tron script so here it is. Just remeber it's in porteguese

Tron Script Website

May 4, 2022

Whether you’re selling it, trashing it, or reusing it, your old computer has a bunch of extremely private data stored inside. And there’s a good chance that tossing files in the recycling bin and hitting factory reset won't protect you. If a hacker finds the pattern your computer used to move those 0s and 1s around, they can reverse engineer the original state of your computer and pull out the goods.

To stay safe, you need to properly factory reset your computer before it ever changes hands. Follow the steps below, or consider taking things a step further by hiring a professional company to ensure your data has been destroyed.

Sign In

Profiles

Forums

Downloads

Gallery

Events

Articles

Posts posted by chain

How to install:

How to Uninstall: